#!/bin/bash

BOINCDIR=/sciezka/do/BOINC
cd $BOINCDIR
for PROJECT in `command ls -1 $BOINCDIR/projects | tr _ /`;do
./boinc_cmd --project http://$PROJECT update
done

#!/usr/bin/perl -w

use strict;
use warnings;
use XML::Simple;
use POSIX qw(strftime);
use lib qw( /ścieżka/do/katalogu/z/modułem/RRDs );
use RRDs;

my $BOINC_DIR = '/scieżka/do/BOINC';
my $BOINC_CMD = $BOINC_DIR.'/boinc_cmd';
my $WORKDIR = '/ściezka/do/katalogu/z/plikami/rrd';

chdir $BOINC_DIR;
opendir my $dh, 'projects';
my $dir = [ ];
@$dir = readdir($dh); # pobieramy listę projektów

my $timestamp = time;
my $ftime = strftime('%Y-%m-%d %H\:%M\:%S %Z',localtime($timestamp)); # stopka na wykresie

# ogólny wygląd wykresu
my @graph_defaults = (
"--slope",
"--font=DEFAULT:6:$WORKDIR/fleftex.ttf", # tu użyłem niestandardowej czcionki, więc w przypadku jej braku wykres rozjedzie się
"--width=269",
"--height=269",
"--lower-limit=0",
"--units=si",
"--rigid",
"--color=BACK#ffffff00",
"--color=CANVAS#ffffff00",
"--color=AXIS#000000",
"--color=FONT#000000",
"--color=MGRID#00000030",
"--color=GRID#00000020",
"--color=SHADEA#F5F5F500",
"--color=SHADEB#F0F0F000",
"--color=ARROW#000000",
);

my $projects = {};
my $totals = {};

foreach ( @$dir ) { # przetwarzamy każdy z projektów
    next if m'^\.';
    print "$_...\n";

    unless ( -r "$WORKDIR/$_.rrd" ) { # tworzymy jednorazowo bazę dla konkretnego projektu
        RRDs::create "$WORKDIR/$_.rrd","--start=now-30d",
            "--step=3600",
            "DS:user_total_credit:GAUGE:86400:0:U",
            "DS:user_expavg_credit:GAUGE:86400:0:U",
            "RRA:LAST:0.5:1:20000",
            ;
    }
   
    # czytamy dane z plików xml
    my $account = read_xml("$BOINC_DIR/account_${_}.xml");
    my $statistics = read_xml("$BOINC_DIR/statistics_${_}.xml");

    # wyciągamy interesujące nas dane
    $projects->{$_}{user_total_credit} = $statistics->{daily_statistics}[-1]{user_total_credit};
    $projects->{$_}{user_expavg_credit} = $statistics->{daily_statistics}[-1]{user_expavg_credit};

    $totals->{user_total_credit} += $projects->{$_}{user_total_credit};
    $totals->{user_expavg_credit} += $projects->{$_}{user_expavg_credit};
   
    # w którymś z projektów 'projekt_name' okazał się pusty przez jakiś czas
    # więc zatąpiłem go urlem
    $projects->{$_}{name} = $account->{project_name} || $account->{master_url};

    # aktualizujemy bazę
    RRDs::update ( "$WORKDIR/$_.rrd","$timestamp:$projects->{$_}{user_total_credit}:$projects->{$_}{user_expavg_credit}");
    if ( my $err = RRDs::error ) {print "update: $err\n"}
}

# tablica z kolorami dla projektów
# zawartoś tablicy to np.: [ 'FF0000' , 'FF9900' ... ] czyli mozna sobie ustawić kolory wedle upodobań
my @colors;
my $total = keys %$projects;
for ( my $i = 0;$i < $total;$i++ ) {
    push @colors,hsv2rgb($i/$total*360,1,1);
}

# sortujemy wykres po RAC
my @prosort = sort { $projects->{$b}{user_expavg_credit} <=> $projects->{$a}{user_expavg_credit} } keys %$projects;

# lub po nazwie projektu
#my @prosort = sort { uc($projects->{$a}{name}) cmp uc($projects->{$b}{name}) } keys %$projects;

# maksymalna wysokość wykresu
$totals->{user_total_credit} *= 1.05;
$totals->{user_expavg_credit} *= 1.05;

# tworzymy wykresy
foreach my $target ( qw (user_total_credit user_expavg_credit) ) {
    do_graph($target);
}

exit;

# wykres
sub do_graph {
    my $target = shift;
    my $i = 0;
    my $title;

    my @graphs;
    my @stack;

    foreach my $project ( @prosort ) {
        (my $project_name = $projects->{$project}{name}) =~ s/:/\\:/g; # gdy w nazie projektu pojawi się ':' musimy go 'poprawić'
        push @stack,"$target$i"; # ustawiamy odpowiednie nazwy zmiennych dla wyrażeń RPN

        if ( $target eq 'user_expavg_credit') {
            $title = 'boinc racs';
            push @graphs,
                "DEF:$target$i=$WORKDIR/$project.rrd:$target:LAST",
                "AREA:$target$i#$colors[$i]:$project_name ".'.' x (41 - length($projects->{$project}{name})).":STACK",
                "GPRINT:$target$i:LAST:%8.2lf\\n";
        }

        if ( $target eq 'user_total_credit' ) {
            $title = 'boinc totals';
            push @graphs,
                "DEF:$target$i=$WORKDIR/$project.rrd:$target:LAST",
                "AREA:$target$i#$colors[$i]:$project_name ".'.' x (36 - length($projects->{$project}{name})).":STACK",
                "GPRINT:$target$i:LAST:%11.2lf\\n";
        }
        $i++;
    }

    if ( $target eq 'user_expavg_credit' ) {
        push @graphs,
            "COMMENT: \\n",
            "--upper-limit=$totals->{user_expavg_credit}",
            "CDEF:total=".join(',', @stack).',+' x (@stack - 1),
            "GPRINT:total:LAST:TOTAL ".'.' x (43 - length('total'))." %9.2lf\\n";
    }

    if ( $target eq 'user_total_credit' ) {
        push @graphs,
            "COMMENT: \\n",
            "--upper-limit=$totals->{user_total_credit}",
            "CDEF:total=".join(',', @stack).',+' x (@stack - 1), # sumujemy dane z wszystkich projektów
            "GPRINT:total:LAST:TOTAL ".'.' x (38 - length('total'))."  %11.2lf\\n";
    }

    RRDs::graph "$WORKDIR/$target.png",
        "--title=$title",
        "--start=1215129600", # start wykresów
        @graph_defaults,
        @graphs,
        "COMMENT: \\n",
        "COMMENT:generated \@ $ftime\\r",
        ;
    if ( my $err = RRDs::error ) {print "graph:$target: $err\n"}
}

# czytanie plików xml
sub read_xml {
    my $path = shift;
    my $content = XMLin( $path, ForceArray => ['daily_statistics'],  SuppressEmpty => 1, NormalizeSpace => 2, KeyAttr => '', );
    return $content;
}

sub dec2hex {
    return sprintf "%02x",int shift;
}

# dla łatwego rysowania 'tęczy', wykorzystałem funkcję zamieniającą model kolorów HSV na RGB
# źródło: wiki :)
sub hsv2rgb {
    my ($h,$s,$v) = @_;
    my $hi = int($h/60) % 6;
    my $f = $h/60 - int($h/60);
    my $p = $v * (1 - $s);
    my $q = $v * (1 - $f * $s);
    my $t = $v * (1 - (1 - $f) * $s);

    for ($v,$t,$p,$q) {
        $_ *= 255;
        $_ = dec2hex($_);
    }

    return "$v$t$p" if $hi == 0;
    return "$q$v$p" if $hi == 1;
    return "$p$v$t" if $hi == 2;
    return "$p$q$v" if $hi == 3;
    return "$t$p$v" if $hi == 4;
    return "$v$p$q" if $hi == 5;
}

next if m'^\.';

next if /^\./;